#!/bin/csh -f


set uname = `uname`;
set unamer = `uname -r`;


switch ($uname)
    case "Linux":
        set type = "linux";
	breaksw
    case "SunOS":
	switch ($unamer)
	    case "4.1.*":
                set type = "sos";
                breaksw;
	    case "5.5":
                set type = "sol25";
                breaksw;
	    case "5.*":
                set type = "sol";
                breaksw;
            default:
                echo "Can't recognize SunOS revision"
        endsw
	breaksw
    case "OSF1":
        set type = "osf";
        breaksw;
    default:
	echo "Can't recognize system; Linux, Solaris, and OSF supported"
endsw

if (! $?type) exit(1)

echo "System is $type"
if ($type == "sos") then
    echo "SunOS not yet supported"
    exit(1)
endif



### Link the appropriate config file
/bin/rm -f .config
ln -s config/config.$type .config
### And root Makefile
if (-e Makefile) /bin/mv -f Makefile Makefile.bak
ln -s Makefile.in Makefile


set top = `pwd`


### Configure the subdirectories
set subdirs = "util vcond"
foreach f ($subdirs)
   cd $f
   if (-e Makefile) /bin/mv -f Makefile Makefile.bak
   ln -s Makefile.in Makefile
   if ($type == "osf") /bin/rm -f .depend
   if (! -e .depend) touch .depend
#   makedepend -I. -I.. -f .depend *.c >& /dev/null
   cd $top
end

echo "Don't forget to do a 'make depend'."
